Go to the documentation of this file.
00001 *> \brief \b DQRT05
00002 *
00003 *  =========== DOCUMENTATION ===========
00004 *
00005 * Online html documentation available at 
00006 *            http://www.netlib.org/lapack/explore-html/ 
00007 *
00008 *  Definition:
00009 *  ===========
00010 *
00011 *       SUBROUTINE DQRT05(M,N,L,NB,RESULT)
00012 * 
00013 *       .. Scalar Arguments ..
00014 *       INTEGER LWORK, M, N, L, NB, LDT
00015 *       .. Return values ..
00016 *       DOUBLE PRECISION RESULT(6)
00017 *  
00018 *
00019 *> \par Purpose:
00020 *  =============
00021 *>
00022 *> \verbatim
00023 *>
00024 *> DQRT05 tests DTPQRT and DTPMQRT.
00025 *> \endverbatim
00026 *
00027 *  Arguments:
00028 *  ==========
00029 *
00030 *> \param[in] M
00031 *> \verbatim
00032 *>          M is INTEGER
00033 *>          Number of rows in lower part of the test matrix.
00034 *> \endverbatim
00035 *>
00036 *> \param[in] N
00037 *> \verbatim
00038 *>          N is INTEGER
00039 *>          Number of columns in test matrix.
00040 *> \endverbatim
00041 *>
00042 *> \param[in] L
00043 *> \verbatim
00044 *>          L is INTEGER
00045 *>          The number of rows of the upper trapezoidal part the
00046 *>          lower test matrix.  0 <= L <= M.
00047 *> \endverbatim
00048 *>          
00049 *> \param[in] NB
00050 *> \verbatim
00051 *>          NB is INTEGER
00052 *>          Block size of test matrix.  NB <= N.
00053 *> \endverbatim
00054 *>
00055 *> \param[out] RESULT
00056 *> \verbatim
00057 *>          RESULT is DOUBLE PRECISION array, dimension (6)
00058 *>          Results of each of the six tests below.
00059 *>
00060 *>          RESULT(1) = | A - Q R |
00061 *>          RESULT(2) = | I - Q^H Q |
00062 *>          RESULT(3) = | Q C - Q C |
00063 *>          RESULT(4) = | Q^H C - Q^H C |
00064 *>          RESULT(5) = | C Q - C Q | 
00065 *>          RESULT(6) = | C Q^H - C Q^H |
00066 *> \endverbatim
00067 *
00068 *  Authors:
00069 *  ========
00070 *
00071 *> \author Univ. of Tennessee 
00072 *> \author Univ. of California Berkeley 
00073 *> \author Univ. of Colorado Denver 
00074 *> \author NAG Ltd. 
00075 *
00076 *> \date November 2011
00077 *
00078 *> \ingroup double_lin
00079 *
00080 *  =====================================================================
00081       SUBROUTINE DQRT05(M,N,L,NB,RESULT)
00082 *
00083 *  -- LAPACK test routine (version 3.4.0) --
00084 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00085 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00086 *     November 2011
00087 *
00088 *     .. Scalar Arguments ..
00089       INTEGER LWORK, M, N, L, NB, LDT
00090 *     .. Return values ..
00091       DOUBLE PRECISION RESULT(6)
00092 *
00093 *  =====================================================================
00094 *      
00095 *     ..
00096 *     .. Local allocatable arrays 
00097       DOUBLE PRECISION, ALLOCATABLE :: AF(:,:), Q(:,:),
00098      $  R(:,:), RWORK(:), WORK( : ), T(:,:), 
00099      $  CF(:,:), DF(:,:), A(:,:), C(:,:), D(:,:)
00100 *
00101 *     .. Parameters ..
00102       DOUBLE PRECISION ONE, ZERO
00103       PARAMETER( ZERO = 0.0, ONE = 1.0 )
00104 *     ..
00105 *     .. Local Scalars ..
00106       INTEGER INFO, J, K, M2
00107       DOUBLE PRECISION   ANORM, EPS, RESID, CNORM, DNORM
00108 *     ..
00109 *     .. Local Arrays ..
00110       INTEGER            ISEED( 4 )
00111 *     ..
00112 *     .. External Functions ..
00113       DOUBLE PRECISION DLAMCH, DLANGE, DLANSY
00114       LOGICAL  LSAME
00115       EXTERNAL DLAMCH, DLANGE, DLANSY, LSAME
00116 *     ..
00117 *     .. Data statements ..
00118       DATA ISEED / 1988, 1989, 1990, 1991 /
00119 *      
00120       EPS = DLAMCH( 'Epsilon' )
00121       K = N
00122       M2 = M+N
00123       LWORK = M2*M2*NB
00124 *
00125 *     Dynamically allocate all arrays
00126 *
00127       ALLOCATE(A(M2,N),AF(M2,N),Q(M2,M2),R(M2,M2),RWORK(M2),
00128      $           WORK(LWORK),T(NB,N),C(M2,N),CF(M2,N), 
00129      $           D(N,M2),DF(N,M2) )
00130 *
00131 *     Put random stuff into A
00132 *
00133       LDT=NB
00134       CALL DLASET( 'Full', M2, N, ZERO, ZERO, A, M2 )
00135       DO J=1,N
00136          CALL DLARNV( 2, ISEED, J, A( 1, J ) )
00137          CALL DLARNV( 2, ISEED, M-L, A( MIN(N+M,N+1), J ) )
00138          CALL DLARNV( 2, ISEED, MIN(J,L), A( MIN(N+M,N+M-L+1), J ) )
00139       END DO
00140 *
00141 *     Copy the matrix A to the array AF.
00142 *
00143       CALL DLACPY( 'Full', M2, N, A, M2, AF, M2 )
00144 *
00145 *     Factor the matrix A in the array AF.
00146 *
00147       CALL DTPQRT( M,N,L,NB,AF,M2,AF(N+1,1),M2,T,LDT,WORK,INFO)
00148 *
00149 *     Generate the (M+N)-by-(M+N) matrix Q by applying H to I
00150 *
00151       CALL DLASET( 'Full', M2, M2, ZERO, ONE, Q, M2 )
00152       CALL DGEMQRT( 'R', 'N', M2, M2, K, NB, AF, M2, T, LDT, Q, M2,
00153      $              WORK, INFO )
00154 *
00155 *     Copy R
00156 *
00157       CALL DLASET( 'Full', M2, N, ZERO, ZERO, R, M2 )
00158       CALL DLACPY( 'Upper', M2, N, AF, M2, R, M2 )
00159 *
00160 *     Compute |R - Q'*A| / |A| and store in RESULT(1)
00161 *
00162       CALL DGEMM( 'T', 'N', M2, N, M2, -ONE, Q, M2, A, M2, ONE, R, M2 )
00163       ANORM = DLANGE( '1', M2, N, A, M2, RWORK )
00164       RESID = DLANGE( '1', M2, N, R, M2, RWORK )
00165       IF( ANORM.GT.ZERO ) THEN
00166          RESULT( 1 ) = RESID / (EPS*ANORM*MAX(1,M2))
00167       ELSE
00168          RESULT( 1 ) = ZERO
00169       END IF
00170 *
00171 *     Compute |I - Q'*Q| and store in RESULT(2)
00172 *
00173       CALL DLASET( 'Full', M2, M2, ZERO, ONE, R, M2 )
00174       CALL DSYRK( 'U', 'C', M2, M2, -ONE, Q, M2, ONE, R, M2 )
00175       RESID = DLANSY( '1', 'Upper', M2, R, M2, RWORK )
00176       RESULT( 2 ) = RESID / (EPS*MAX(1,M2))
00177 *
00178 *     Generate random m-by-n matrix C and a copy CF
00179 *
00180       DO J=1,N
00181          CALL DLARNV( 2, ISEED, M2, C( 1, J ) )
00182       END DO
00183       CNORM = DLANGE( '1', M2, N, C, M2, RWORK)
00184       CALL DLACPY( 'Full', M2, N, C, M2, CF, M2 )
00185 *
00186 *     Apply Q to C as Q*C
00187 *
00188       CALL DTPMQRT( 'L','N', M,N,K,L,NB,AF(N+1,1),M2,T,LDT,CF,M2,
00189      $               CF(N+1,1),M2,WORK,INFO)
00190 *
00191 *     Compute |Q*C - Q*C| / |C|
00192 *
00193       CALL DGEMM( 'N', 'N', M2, N, M2, -ONE, Q, M2, C, M2, ONE, CF, M2 )
00194       RESID = DLANGE( '1', M2, N, CF, M2, RWORK )
00195       IF( CNORM.GT.ZERO ) THEN
00196          RESULT( 3 ) = RESID / (EPS*MAX(1,M2)*CNORM)
00197       ELSE
00198          RESULT( 3 ) = ZERO
00199       END IF
00200 *
00201 *     Copy C into CF again
00202 *
00203       CALL DLACPY( 'Full', M2, N, C, M2, CF, M2 )
00204 *
00205 *     Apply Q to C as QT*C
00206 *
00207       CALL DTPMQRT( 'L','T',M,N,K,L,NB,AF(N+1,1),M2,T,LDT,CF,M2,
00208      $              CF(N+1,1),M2,WORK,INFO) 
00209 *
00210 *     Compute |QT*C - QT*C| / |C|
00211 *
00212       CALL DGEMM('T','N',M2,N,M2,-ONE,Q,M2,C,M2,ONE,CF,M2)
00213       RESID = DLANGE( '1', M2, N, CF, M2, RWORK )
00214       IF( CNORM.GT.ZERO ) THEN
00215          RESULT( 4 ) = RESID / (EPS*MAX(1,M2)*CNORM)
00216       ELSE
00217          RESULT( 4 ) = ZERO
00218       END IF     
00219 *
00220 *     Generate random n-by-m matrix D and a copy DF
00221 *
00222       DO J=1,M2
00223          CALL DLARNV( 2, ISEED, N, D( 1, J ) )
00224       END DO
00225       DNORM = DLANGE( '1', N, M2, D, N, RWORK)
00226       CALL DLACPY( 'Full', N, M2, D, N, DF, N )
00227 *
00228 *     Apply Q to D as D*Q
00229 *
00230       CALL DTPMQRT('R','N',N,M,N,L,NB,AF(N+1,1),M2,T,LDT,DF,N,
00231      $             DF(1,N+1),N,WORK,INFO)
00232 *
00233 *     Compute |D*Q - D*Q| / |D|
00234 *
00235       CALL DGEMM('N','N',N,M2,M2,-ONE,D,N,Q,M2,ONE,DF,N)
00236       RESID = DLANGE('1',N, M2,DF,N,RWORK )
00237       IF( CNORM.GT.ZERO ) THEN
00238          RESULT( 5 ) = RESID / (EPS*MAX(1,M2)*DNORM)
00239       ELSE
00240          RESULT( 5 ) = ZERO
00241       END IF
00242 *
00243 *     Copy D into DF again
00244 *
00245       CALL DLACPY('Full',N,M2,D,N,DF,N )
00246 *
00247 *     Apply Q to D as D*QT
00248 *
00249       CALL DTPMQRT('R','T',N,M,N,L,NB,AF(N+1,1),M2,T,LDT,DF,N,
00250      $             DF(1,N+1),N,WORK,INFO)     
00251        
00252 *
00253 *     Compute |D*QT - D*QT| / |D|
00254 *
00255       CALL DGEMM( 'N', 'T', N, M2, M2, -ONE, D, N, Q, M2, ONE, DF, N )
00256       RESID = DLANGE( '1', N, M2, DF, N, RWORK )
00257       IF( CNORM.GT.ZERO ) THEN
00258          RESULT( 6 ) = RESID / (EPS*MAX(1,M2)*DNORM)
00259       ELSE
00260          RESULT( 6 ) = ZERO
00261       END IF
00262 *
00263 *     Deallocate all arrays
00264 *
00265       DEALLOCATE ( A, AF, Q, R, RWORK, WORK, T, C, D, CF, DF)
00266       RETURN
00267       END
00268