Go to the documentation of this file.
00001 *> \brief \b CLA_HERCOND_X
00002 *
00003 *  =========== DOCUMENTATION ===========
00004 *
00005 * Online html documentation available at 
00006 *            http://www.netlib.org/lapack/explore-html/ 
00007 *
00008 *> \htmlonly
00009 *> Download CLA_HERCOND_X + dependencies 
00010 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cla_hercond_x.f"> 
00011 *> [TGZ]</a> 
00012 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cla_hercond_x.f"> 
00013 *> [ZIP]</a> 
00014 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cla_hercond_x.f"> 
00015 *> [TXT]</a>
00016 *> \endhtmlonly 
00017 *
00018 *  Definition:
00019 *  ===========
00020 *
00021 *       REAL FUNCTION CLA_HERCOND_X( UPLO, N, A, LDA, AF, LDAF, IPIV, X,
00022 *                                    INFO, WORK, RWORK )
00023 * 
00024 *       .. Scalar Arguments ..
00025 *       CHARACTER          UPLO
00026 *       INTEGER            N, LDA, LDAF, INFO
00027 *       ..
00028 *       .. Array Arguments ..
00029 *       INTEGER            IPIV( * )
00030 *       COMPLEX            A( LDA, * ), AF( LDAF, * ), WORK( * ), X( * )
00031 *       REAL               RWORK( * )
00032 *       ..
00033 *  
00034 *
00035 *> \par Purpose:
00036 *  =============
00037 *>
00038 *> \verbatim
00039 *>
00040 *>    CLA_HERCOND_X computes the infinity norm condition number of
00041 *>    op(A) * diag(X) where X is a COMPLEX vector.
00042 *> \endverbatim
00043 *
00044 *  Arguments:
00045 *  ==========
00046 *
00047 *> \param[in] UPLO
00048 *> \verbatim
00049 *>          UPLO is CHARACTER*1
00050 *>       = 'U':  Upper triangle of A is stored;
00051 *>       = 'L':  Lower triangle of A is stored.
00052 *> \endverbatim
00053 *>
00054 *> \param[in] N
00055 *> \verbatim
00056 *>          N is INTEGER
00057 *>     The number of linear equations, i.e., the order of the
00058 *>     matrix A.  N >= 0.
00059 *> \endverbatim
00060 *>
00061 *> \param[in] A
00062 *> \verbatim
00063 *>          A is COMPLEX array, dimension (LDA,N)
00064 *>     On entry, the N-by-N matrix A.
00065 *> \endverbatim
00066 *>
00067 *> \param[in] LDA
00068 *> \verbatim
00069 *>          LDA is INTEGER
00070 *>     The leading dimension of the array A.  LDA >= max(1,N).
00071 *> \endverbatim
00072 *>
00073 *> \param[in] AF
00074 *> \verbatim
00075 *>          AF is COMPLEX array, dimension (LDAF,N)
00076 *>     The block diagonal matrix D and the multipliers used to
00077 *>     obtain the factor U or L as computed by CHETRF.
00078 *> \endverbatim
00079 *>
00080 *> \param[in] LDAF
00081 *> \verbatim
00082 *>          LDAF is INTEGER
00083 *>     The leading dimension of the array AF.  LDAF >= max(1,N).
00084 *> \endverbatim
00085 *>
00086 *> \param[in] IPIV
00087 *> \verbatim
00088 *>          IPIV is INTEGER array, dimension (N)
00089 *>     Details of the interchanges and the block structure of D
00090 *>     as determined by CHETRF.
00091 *> \endverbatim
00092 *>
00093 *> \param[in] X
00094 *> \verbatim
00095 *>          X is COMPLEX array, dimension (N)
00096 *>     The vector X in the formula op(A) * diag(X).
00097 *> \endverbatim
00098 *>
00099 *> \param[out] INFO
00100 *> \verbatim
00101 *>          INFO is INTEGER
00102 *>       = 0:  Successful exit.
00103 *>     i > 0:  The ith argument is invalid.
00104 *> \endverbatim
00105 *>
00106 *> \param[in] WORK
00107 *> \verbatim
00108 *>          WORK is COMPLEX array, dimension (2*N).
00109 *>     Workspace.
00110 *> \endverbatim
00111 *>
00112 *> \param[in] RWORK
00113 *> \verbatim
00114 *>          RWORK is REAL array, dimension (N).
00115 *>     Workspace.
00116 *> \endverbatim
00117 *
00118 *  Authors:
00119 *  ========
00120 *
00121 *> \author Univ. of Tennessee 
00122 *> \author Univ. of California Berkeley 
00123 *> \author Univ. of Colorado Denver 
00124 *> \author NAG Ltd. 
00125 *
00126 *> \date November 2011
00127 *
00128 *> \ingroup complexHEcomputational
00129 *
00130 *  =====================================================================
00131       REAL FUNCTION CLA_HERCOND_X( UPLO, N, A, LDA, AF, LDAF, IPIV, X,
00132      $                             INFO, WORK, RWORK )
00133 *
00134 *  -- LAPACK computational routine (version 3.4.0) --
00135 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00136 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00137 *     November 2011
00138 *
00139 *     .. Scalar Arguments ..
00140       CHARACTER          UPLO
00141       INTEGER            N, LDA, LDAF, INFO
00142 *     ..
00143 *     .. Array Arguments ..
00144       INTEGER            IPIV( * )
00145       COMPLEX            A( LDA, * ), AF( LDAF, * ), WORK( * ), X( * )
00146       REAL               RWORK( * )
00147 *     ..
00148 *
00149 *  =====================================================================
00150 *
00151 *     .. Local Scalars ..
00152       INTEGER            KASE, I, J
00153       REAL               AINVNM, ANORM, TMP
00154       LOGICAL            UP
00155       COMPLEX            ZDUM
00156 *     ..
00157 *     .. Local Arrays ..
00158       INTEGER            ISAVE( 3 )
00159 *     ..
00160 *     .. External Functions ..
00161       LOGICAL            LSAME
00162       EXTERNAL           LSAME
00163 *     ..
00164 *     .. External Subroutines ..
00165       EXTERNAL           CLACN2, CHETRS, XERBLA
00166 *     ..
00167 *     .. Intrinsic Functions ..
00168       INTRINSIC          ABS, MAX
00169 *     ..
00170 *     .. Statement Functions ..
00171       REAL CABS1
00172 *     ..
00173 *     .. Statement Function Definitions ..
00174       CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
00175 *     ..
00176 *     .. Executable Statements ..
00177 *
00178       CLA_HERCOND_X = 0.0E+0
00179 *
00180       INFO = 0
00181       IF( N.LT.0 ) THEN
00182          INFO = -2
00183       END IF
00184       IF( INFO.NE.0 ) THEN
00185          CALL XERBLA( 'CLA_HERCOND_X', -INFO )
00186          RETURN
00187       END IF
00188       UP = .FALSE.
00189       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
00190 *
00191 *     Compute norm of op(A)*op2(C).
00192 *
00193       ANORM = 0.0
00194       IF ( UP ) THEN
00195          DO I = 1, N
00196             TMP = 0.0E+0
00197             DO J = 1, I
00198                TMP = TMP + CABS1( A( J, I ) * X( J ) )
00199             END DO
00200             DO J = I+1, N
00201                TMP = TMP + CABS1( A( I, J ) * X( J ) )
00202             END DO
00203             RWORK( I ) = TMP
00204             ANORM = MAX( ANORM, TMP )
00205          END DO
00206       ELSE
00207          DO I = 1, N
00208             TMP = 0.0E+0
00209             DO J = 1, I
00210                TMP = TMP + CABS1( A( I, J ) * X( J ) )
00211             END DO
00212             DO J = I+1, N
00213                TMP = TMP + CABS1( A( J, I ) * X( J ) )
00214             END DO
00215             RWORK( I ) = TMP
00216             ANORM = MAX( ANORM, TMP )
00217          END DO
00218       END IF
00219 *
00220 *     Quick return if possible.
00221 *
00222       IF( N.EQ.0 ) THEN
00223          CLA_HERCOND_X = 1.0E+0
00224          RETURN
00225       ELSE IF( ANORM .EQ. 0.0E+0 ) THEN
00226          RETURN
00227       END IF
00228 *
00229 *     Estimate the norm of inv(op(A)).
00230 *
00231       AINVNM = 0.0E+0
00232 *
00233       KASE = 0
00234    10 CONTINUE
00235       CALL CLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
00236       IF( KASE.NE.0 ) THEN
00237          IF( KASE.EQ.2 ) THEN
00238 *
00239 *           Multiply by R.
00240 *
00241             DO I = 1, N
00242                WORK( I ) = WORK( I ) * RWORK( I )
00243             END DO
00244 *
00245             IF ( UP ) THEN
00246                CALL CHETRS( 'U', N, 1, AF, LDAF, IPIV,
00247      $            WORK, N, INFO )
00248             ELSE
00249                CALL CHETRS( 'L', N, 1, AF, LDAF, IPIV,
00250      $            WORK, N, INFO )
00251             ENDIF
00252 *
00253 *           Multiply by inv(X).
00254 *
00255             DO I = 1, N
00256                WORK( I ) = WORK( I ) / X( I )
00257             END DO
00258          ELSE
00259 *
00260 *           Multiply by inv(X**H).
00261 *
00262             DO I = 1, N
00263                WORK( I ) = WORK( I ) / X( I )
00264             END DO
00265 *
00266             IF ( UP ) THEN
00267                CALL CHETRS( 'U', N, 1, AF, LDAF, IPIV,
00268      $            WORK, N, INFO )
00269             ELSE
00270                CALL CHETRS( 'L', N, 1, AF, LDAF, IPIV,
00271      $            WORK, N, INFO )
00272             END IF
00273 *
00274 *           Multiply by R.
00275 *
00276             DO I = 1, N
00277                WORK( I ) = WORK( I ) * RWORK( I )
00278             END DO
00279          END IF
00280          GO TO 10
00281       END IF
00282 *
00283 *     Compute the estimate of the reciprocal condition number.
00284 *
00285       IF( AINVNM .NE. 0.0E+0 )
00286      $   CLA_HERCOND_X = 1.0E+0 / AINVNM
00287 *
00288       RETURN
00289 *
00290       END