Go to the documentation of this file.
00001 *> \brief \b ZLA_SYRCOND_X
00002 *
00003 *  =========== DOCUMENTATION ===========
00004 *
00005 * Online html documentation available at 
00006 *            http://www.netlib.org/lapack/explore-html/ 
00007 *
00008 *> \htmlonly
00009 *> Download ZLA_SYRCOND_X + dependencies 
00010 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zla_syrcond_x.f"> 
00011 *> [TGZ]</a> 
00012 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zla_syrcond_x.f"> 
00013 *> [ZIP]</a> 
00014 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zla_syrcond_x.f"> 
00015 *> [TXT]</a>
00016 *> \endhtmlonly 
00017 *
00018 *  Definition:
00019 *  ===========
00020 *
00021 *       DOUBLE PRECISION FUNCTION ZLA_SYRCOND_X( UPLO, N, A, LDA, AF,
00022 *                                                LDAF, IPIV, X, INFO,
00023 *                                                WORK, RWORK )
00024 * 
00025 *       .. Scalar Arguments ..
00026 *       CHARACTER          UPLO
00027 *       INTEGER            N, LDA, LDAF, INFO
00028 *       ..
00029 *       .. Array Arguments ..
00030 *       INTEGER            IPIV( * )
00031 *       COMPLEX*16         A( LDA, * ), AF( LDAF, * ), WORK( * ), X( * )
00032 *       DOUBLE PRECISION   RWORK( * )
00033 *       ..
00034 *  
00035 *
00036 *> \par Purpose:
00037 *  =============
00038 *>
00039 *> \verbatim
00040 *>
00041 *>    ZLA_SYRCOND_X Computes the infinity norm condition number of
00042 *>    op(A) * diag(X) where X is a COMPLEX*16 vector.
00043 *> \endverbatim
00044 *
00045 *  Arguments:
00046 *  ==========
00047 *
00048 *> \param[in] UPLO
00049 *> \verbatim
00050 *>          UPLO is CHARACTER*1
00051 *>       = 'U':  Upper triangle of A is stored;
00052 *>       = 'L':  Lower triangle of A is stored.
00053 *> \endverbatim
00054 *>
00055 *> \param[in] N
00056 *> \verbatim
00057 *>          N is INTEGER
00058 *>     The number of linear equations, i.e., the order of the
00059 *>     matrix A.  N >= 0.
00060 *> \endverbatim
00061 *>
00062 *> \param[in] A
00063 *> \verbatim
00064 *>          A is COMPLEX*16 array, dimension (LDA,N)
00065 *>     On entry, the N-by-N matrix A.
00066 *> \endverbatim
00067 *>
00068 *> \param[in] LDA
00069 *> \verbatim
00070 *>          LDA is INTEGER
00071 *>     The leading dimension of the array A.  LDA >= max(1,N).
00072 *> \endverbatim
00073 *>
00074 *> \param[in] AF
00075 *> \verbatim
00076 *>          AF is COMPLEX*16 array, dimension (LDAF,N)
00077 *>     The block diagonal matrix D and the multipliers used to
00078 *>     obtain the factor U or L as computed by ZSYTRF.
00079 *> \endverbatim
00080 *>
00081 *> \param[in] LDAF
00082 *> \verbatim
00083 *>          LDAF is INTEGER
00084 *>     The leading dimension of the array AF.  LDAF >= max(1,N).
00085 *> \endverbatim
00086 *>
00087 *> \param[in] IPIV
00088 *> \verbatim
00089 *>          IPIV is INTEGER array, dimension (N)
00090 *>     Details of the interchanges and the block structure of D
00091 *>     as determined by ZSYTRF.
00092 *> \endverbatim
00093 *>
00094 *> \param[in] X
00095 *> \verbatim
00096 *>          X is COMPLEX*16 array, dimension (N)
00097 *>     The vector X in the formula op(A) * diag(X).
00098 *> \endverbatim
00099 *>
00100 *> \param[out] INFO
00101 *> \verbatim
00102 *>          INFO is INTEGER
00103 *>       = 0:  Successful exit.
00104 *>     i > 0:  The ith argument is invalid.
00105 *> \endverbatim
00106 *>
00107 *> \param[in] WORK
00108 *> \verbatim
00109 *>          WORK is COMPLEX*16 array, dimension (2*N).
00110 *>     Workspace.
00111 *> \endverbatim
00112 *>
00113 *> \param[in] RWORK
00114 *> \verbatim
00115 *>          RWORK is DOUBLE PRECISION array, dimension (N).
00116 *>     Workspace.
00117 *> \endverbatim
00118 *
00119 *  Authors:
00120 *  ========
00121 *
00122 *> \author Univ. of Tennessee 
00123 *> \author Univ. of California Berkeley 
00124 *> \author Univ. of Colorado Denver 
00125 *> \author NAG Ltd. 
00126 *
00127 *> \date November 2011
00128 *
00129 *> \ingroup complex16SYcomputational
00130 *
00131 *  =====================================================================
00132       DOUBLE PRECISION FUNCTION ZLA_SYRCOND_X( UPLO, N, A, LDA, AF,
00133      $                                         LDAF, IPIV, X, INFO,
00134      $                                         WORK, RWORK )
00135 *
00136 *  -- LAPACK computational routine (version 3.4.0) --
00137 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00138 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00139 *     November 2011
00140 *
00141 *     .. Scalar Arguments ..
00142       CHARACTER          UPLO
00143       INTEGER            N, LDA, LDAF, INFO
00144 *     ..
00145 *     .. Array Arguments ..
00146       INTEGER            IPIV( * )
00147       COMPLEX*16         A( LDA, * ), AF( LDAF, * ), WORK( * ), X( * )
00148       DOUBLE PRECISION   RWORK( * )
00149 *     ..
00150 *
00151 *  =====================================================================
00152 *
00153 *     .. Local Scalars ..
00154       INTEGER            KASE
00155       DOUBLE PRECISION   AINVNM, ANORM, TMP
00156       INTEGER            I, J
00157       LOGICAL            UP
00158       COMPLEX*16         ZDUM
00159 *     ..
00160 *     .. Local Arrays ..
00161       INTEGER            ISAVE( 3 )
00162 *     ..
00163 *     .. External Functions ..
00164       LOGICAL            LSAME
00165       EXTERNAL           LSAME
00166 *     ..
00167 *     .. External Subroutines ..
00168       EXTERNAL           ZLACN2, ZSYTRS, XERBLA
00169 *     ..
00170 *     .. Intrinsic Functions ..
00171       INTRINSIC          ABS, MAX
00172 *     ..
00173 *     .. Statement Functions ..
00174       DOUBLE PRECISION   CABS1
00175 *     ..
00176 *     .. Statement Function Definitions ..
00177       CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
00178 *     ..
00179 *     .. Executable Statements ..
00180 *
00181       ZLA_SYRCOND_X = 0.0D+0
00182 *
00183       INFO = 0
00184       IF( N.LT.0 ) THEN
00185          INFO = -2
00186       END IF
00187       IF( INFO.NE.0 ) THEN
00188          CALL XERBLA( 'ZLA_SYRCOND_X', -INFO )
00189          RETURN
00190       END IF
00191       UP = .FALSE.
00192       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
00193 *
00194 *     Compute norm of op(A)*op2(C).
00195 *
00196       ANORM = 0.0D+0
00197       IF ( UP ) THEN
00198          DO I = 1, N
00199             TMP = 0.0D+0
00200             DO J = 1, I
00201                TMP = TMP + CABS1( A( J, I ) * X( J ) )
00202             END DO
00203             DO J = I+1, N
00204                TMP = TMP + CABS1( A( I, J ) * X( J ) )
00205             END DO
00206             RWORK( I ) = TMP
00207             ANORM = MAX( ANORM, TMP )
00208          END DO
00209       ELSE
00210          DO I = 1, N
00211             TMP = 0.0D+0
00212             DO J = 1, I
00213                TMP = TMP + CABS1( A( I, J ) * X( J ) )
00214             END DO
00215             DO J = I+1, N
00216                TMP = TMP + CABS1( A( J, I ) * X( J ) )
00217             END DO
00218             RWORK( I ) = TMP
00219             ANORM = MAX( ANORM, TMP )
00220          END DO
00221       END IF
00222 *
00223 *     Quick return if possible.
00224 *
00225       IF( N.EQ.0 ) THEN
00226          ZLA_SYRCOND_X = 1.0D+0
00227          RETURN
00228       ELSE IF( ANORM .EQ. 0.0D+0 ) THEN
00229          RETURN
00230       END IF
00231 *
00232 *     Estimate the norm of inv(op(A)).
00233 *
00234       AINVNM = 0.0D+0
00235 *
00236       KASE = 0
00237    10 CONTINUE
00238       CALL ZLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
00239       IF( KASE.NE.0 ) THEN
00240          IF( KASE.EQ.2 ) THEN
00241 *
00242 *           Multiply by R.
00243 *
00244             DO I = 1, N
00245                WORK( I ) = WORK( I ) * RWORK( I )
00246             END DO
00247 *
00248             IF ( UP ) THEN
00249                CALL ZSYTRS( 'U', N, 1, AF, LDAF, IPIV,
00250      $            WORK, N, INFO )
00251             ELSE
00252                CALL ZSYTRS( 'L', N, 1, AF, LDAF, IPIV,
00253      $            WORK, N, INFO )
00254             ENDIF
00255 *
00256 *           Multiply by inv(X).
00257 *
00258             DO I = 1, N
00259                WORK( I ) = WORK( I ) / X( I )
00260             END DO
00261          ELSE
00262 *
00263 *           Multiply by inv(X**T).
00264 *
00265             DO I = 1, N
00266                WORK( I ) = WORK( I ) / X( I )
00267             END DO
00268 *
00269             IF ( UP ) THEN
00270                CALL ZSYTRS( 'U', N, 1, AF, LDAF, IPIV,
00271      $            WORK, N, INFO )
00272             ELSE
00273                CALL ZSYTRS( 'L', N, 1, AF, LDAF, IPIV,
00274      $            WORK, N, INFO )
00275             END IF
00276 *
00277 *           Multiply by R.
00278 *
00279             DO I = 1, N
00280                WORK( I ) = WORK( I ) * RWORK( I )
00281             END DO
00282          END IF
00283          GO TO 10
00284       END IF
00285 *
00286 *     Compute the estimate of the reciprocal condition number.
00287 *
00288       IF( AINVNM .NE. 0.0D+0 )
00289      $   ZLA_SYRCOND_X = 1.0D+0 / AINVNM
00290 *
00291       RETURN
00292 *
00293       END