Go to the documentation of this file.
00001 *> \brief \b CQRT05
00002 *
00003 *  =========== DOCUMENTATION ===========
00004 *
00005 * Online html documentation available at 
00006 *            http://www.netlib.org/lapack/explore-html/ 
00007 *
00008 *  Definition:
00009 *  ===========
00010 *
00011 *       SUBROUTINE CQRT05(M,N,L,NB,RESULT)
00012 * 
00013 *       .. Scalar Arguments ..
00014 *       INTEGER LWORK, M, N, L, NB, LDT
00015 *       .. Return values ..
00016 *       REAL RESULT(6)
00017 *  
00018 *
00019 *> \par Purpose:
00020 *  =============
00021 *>
00022 *> \verbatim
00023 *>
00024 *> CQRT05 tests CTPQRT and CTPMQRT.
00025 *> \endverbatim
00026 *
00027 *  Arguments:
00028 *  ==========
00029 *
00030 *> \param[in] M
00031 *> \verbatim
00032 *>          M is INTEGER
00033 *>          Number of rows in lower part of the test matrix.
00034 *> \endverbatim
00035 *>
00036 *> \param[in] N
00037 *> \verbatim
00038 *>          N is INTEGER
00039 *>          Number of columns in test matrix.
00040 *> \endverbatim
00041 *>
00042 *> \param[in] L
00043 *> \verbatim
00044 *>          L is INTEGER
00045 *>          The number of rows of the upper trapezoidal part the
00046 *>          lower test matrix.  0 <= L <= M.
00047 *> \endverbatim
00048 *>          
00049 *> \param[in] NB
00050 *> \verbatim
00051 *>          NB is INTEGER
00052 *>          Block size of test matrix.  NB <= N.
00053 *> \endverbatim
00054 *>
00055 *> \param[out] RESULT
00056 *> \verbatim
00057 *>          RESULT is REAL array, dimension (6)
00058 *>          Results of each of the six tests below.
00059 *>
00060 *>          RESULT(1) = | A - Q R |
00061 *>          RESULT(2) = | I - Q^H Q |
00062 *>          RESULT(3) = | Q C - Q C |
00063 *>          RESULT(4) = | Q^H C - Q^H C |
00064 *>          RESULT(5) = | C Q - C Q | 
00065 *>          RESULT(6) = | C Q^H - C Q^H |
00066 *> \endverbatim
00067 *
00068 *  Authors:
00069 *  ========
00070 *
00071 *> \author Univ. of Tennessee 
00072 *> \author Univ. of California Berkeley 
00073 *> \author Univ. of Colorado Denver 
00074 *> \author NAG Ltd. 
00075 *
00076 *> \date November 2011
00077 *
00078 *> \ingroup complex_lin
00079 *
00080 *  =====================================================================
00081       SUBROUTINE CQRT05(M,N,L,NB,RESULT)
00082 *
00083 *  -- LAPACK test routine (version 3.4.0) --
00084 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00085 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00086 *     November 2011
00087 *
00088 *     .. Scalar Arguments ..
00089       INTEGER LWORK, M, N, L, NB, LDT
00090 *     .. Return values ..
00091       REAL RESULT(6)
00092 *
00093 *  =====================================================================
00094 *      
00095 *     ..
00096 *     .. Local allocatable arrays 
00097       COMPLEX, ALLOCATABLE :: AF(:,:), Q(:,:),
00098      $  R(:,:), RWORK(:), WORK( : ), T(:,:), 
00099      $  CF(:,:), DF(:,:), A(:,:), C(:,:), D(:,:)
00100 *
00101 *     .. Parameters ..
00102       REAL ZERO
00103       COMPLEX ONE, CZERO
00104       PARAMETER( ZERO = 0.0, ONE = (1.0,0.0), CZERO=(0.0,0.0) )
00105 *     ..
00106 *     .. Local Scalars ..
00107       INTEGER INFO, J, K, M2
00108       REAL   ANORM, EPS, RESID, CNORM, DNORM
00109 *     ..
00110 *     .. Local Arrays ..
00111       INTEGER            ISEED( 4 )
00112 *     ..
00113 *     .. External Functions ..
00114       REAL SLAMCH 
00115       REAL CLANGE, CLANSY
00116       LOGICAL  LSAME
00117       EXTERNAL SLAMCH, CLANGE, CLANSY, LSAME
00118 *     ..
00119 *     .. Data statements ..
00120       DATA ISEED / 1988, 1989, 1990, 1991 /
00121 *      
00122       EPS = SLAMCH( 'Epsilon' )
00123       K = N
00124       M2 = M+N
00125       LWORK = M2*M2*NB
00126 *
00127 *     Dynamically allocate all arrays
00128 *
00129       ALLOCATE(A(M2,N),AF(M2,N),Q(M2,M2),R(M2,M2),RWORK(M2),
00130      $           WORK(LWORK),T(NB,N),C(M2,N),CF(M2,N), 
00131      $           D(N,M2),DF(N,M2) )
00132 *
00133 *     Put random stuff into A
00134 *
00135       LDT=NB
00136       CALL CLASET( 'Full', M2, N, CZERO, CZERO, A, M2 )
00137       DO J=1,N
00138          CALL CLARNV( 2, ISEED, J, A( 1, J ) )
00139          CALL CLARNV( 2, ISEED, M-L, A( MIN(N+M,N+1), J ) )
00140          CALL CLARNV( 2, ISEED, MIN(J,L), A( MIN(N+M,N+M-L+1), J ) )
00141       END DO
00142 *
00143 *     Copy the matrix A to the array AF.
00144 *
00145       CALL CLACPY( 'Full', M2, N, A, M2, AF, M2 )
00146 *
00147 *     Factor the matrix A in the array AF.
00148 *
00149       CALL CTPQRT( M,N,L,NB,AF,M2,AF(N+1,1),M2,T,LDT,WORK,INFO)
00150 *
00151 *     Generate the (M+N)-by-(M+N) matrix Q by applying H to I
00152 *
00153       CALL CLASET( 'Full', M2, M2, CZERO, ONE, Q, M2 )
00154       CALL CGEMQRT( 'R', 'N', M2, M2, K, NB, AF, M2, T, LDT, Q, M2,
00155      $              WORK, INFO )
00156 *
00157 *     Copy R
00158 *
00159       CALL CLASET( 'Full', M2, N, CZERO, CZERO, R, M2 )
00160       CALL CLACPY( 'Upper', M2, N, AF, M2, R, M2 )
00161 *
00162 *     Compute |R - Q'*A| / |A| and store in RESULT(1)
00163 *
00164       CALL CGEMM( 'C', 'N', M2, N, M2, -ONE, Q, M2, A, M2, ONE, R, M2 )
00165       ANORM = CLANGE( '1', M2, N, A, M2, RWORK )
00166       RESID = CLANGE( '1', M2, N, R, M2, RWORK )
00167       IF( ANORM.GT.ZERO ) THEN
00168          RESULT( 1 ) = RESID / (EPS*ANORM*MAX(1,M2))
00169       ELSE
00170          RESULT( 1 ) = ZERO
00171       END IF
00172 *
00173 *     Compute |I - Q'*Q| and store in RESULT(2)
00174 *
00175       CALL CLASET( 'Full', M2, M2, CZERO, ONE, R, M2 )
00176       CALL CHERK( 'U', 'C', M2, M2, REAL(-ONE), Q, M2, REAL(ONE), 
00177      $            R, M2 )
00178       RESID = CLANSY( '1', 'Upper', M2, R, M2, RWORK )
00179       RESULT( 2 ) = RESID / (EPS*MAX(1,M2))
00180 *
00181 *     Generate random m-by-n matrix C and a copy CF
00182 *
00183       DO J=1,N
00184          CALL CLARNV( 2, ISEED, M2, C( 1, J ) )
00185       END DO
00186       CNORM = CLANGE( '1', M2, N, C, M2, RWORK)
00187       CALL CLACPY( 'Full', M2, N, C, M2, CF, M2 )
00188 *
00189 *     Apply Q to C as Q*C
00190 *
00191       CALL CTPMQRT( 'L','N', M,N,K,L,NB,AF(N+1,1),M2,T,LDT,CF,M2,
00192      $               CF(N+1,1),M2,WORK,INFO)
00193 *
00194 *     Compute |Q*C - Q*C| / |C|
00195 *
00196       CALL CGEMM( 'N', 'N', M2, N, M2, -ONE, Q, M2, C, M2, ONE, CF, M2 )
00197       RESID = CLANGE( '1', M2, N, CF, M2, RWORK )
00198       IF( CNORM.GT.ZERO ) THEN
00199          RESULT( 3 ) = RESID / (EPS*MAX(1,M2)*CNORM)
00200       ELSE
00201          RESULT( 3 ) = ZERO
00202       END IF
00203 *
00204 *     Copy C into CF again
00205 *
00206       CALL CLACPY( 'Full', M2, N, C, M2, CF, M2 )
00207 *
00208 *     Apply Q to C as QT*C
00209 *
00210       CALL CTPMQRT( 'L','C',M,N,K,L,NB,AF(N+1,1),M2,T,LDT,CF,M2,
00211      $              CF(N+1,1),M2,WORK,INFO) 
00212 *
00213 *     Compute |QT*C - QT*C| / |C|
00214 *
00215       CALL CGEMM('C','N',M2,N,M2,-ONE,Q,M2,C,M2,ONE,CF,M2)
00216       RESID = CLANGE( '1', M2, N, CF, M2, RWORK )
00217       IF( CNORM.GT.ZERO ) THEN
00218          RESULT( 4 ) = RESID / (EPS*MAX(1,M2)*CNORM)
00219       ELSE
00220          RESULT( 4 ) = ZERO
00221       END IF     
00222 *
00223 *     Generate random n-by-m matrix D and a copy DF
00224 *
00225       DO J=1,M2
00226          CALL CLARNV( 2, ISEED, N, D( 1, J ) )
00227       END DO
00228       DNORM = CLANGE( '1', N, M2, D, N, RWORK)
00229       CALL CLACPY( 'Full', N, M2, D, N, DF, N )
00230 *
00231 *     Apply Q to D as D*Q
00232 *
00233       CALL CTPMQRT('R','N',N,M,N,L,NB,AF(N+1,1),M2,T,LDT,DF,N,
00234      $             DF(1,N+1),N,WORK,INFO)
00235 *
00236 *     Compute |D*Q - D*Q| / |D|
00237 *
00238       CALL CGEMM('N','N',N,M2,M2,-ONE,D,N,Q,M2,ONE,DF,N)
00239       RESID = CLANGE('1',N, M2,DF,N,RWORK )
00240       IF( CNORM.GT.ZERO ) THEN
00241          RESULT( 5 ) = RESID / (EPS*MAX(1,M2)*DNORM)
00242       ELSE
00243          RESULT( 5 ) = ZERO
00244       END IF
00245 *
00246 *     Copy D into DF again
00247 *
00248       CALL CLACPY('Full',N,M2,D,N,DF,N )
00249 *
00250 *     Apply Q to D as D*QT
00251 *
00252       CALL CTPMQRT('R','C',N,M,N,L,NB,AF(N+1,1),M2,T,LDT,DF,N,
00253      $             DF(1,N+1),N,WORK,INFO)     
00254        
00255 *
00256 *     Compute |D*QT - D*QT| / |D|
00257 *
00258       CALL CGEMM( 'N', 'C', N, M2, M2, -ONE, D, N, Q, M2, ONE, DF, N )
00259       RESID = CLANGE( '1', N, M2, DF, N, RWORK )
00260       IF( CNORM.GT.ZERO ) THEN
00261          RESULT( 6 ) = RESID / (EPS*MAX(1,M2)*DNORM)
00262       ELSE
00263          RESULT( 6 ) = ZERO
00264       END IF
00265 *
00266 *     Deallocate all arrays
00267 *
00268       DEALLOCATE ( A, AF, Q, R, RWORK, WORK, T, C, D, CF, DF)
00269       RETURN
00270       END
00271