Go to the documentation of this file.
00001 *> \brief \b DLA_SYRCOND
00002 *
00003 *  =========== DOCUMENTATION ===========
00004 *
00005 * Online html documentation available at 
00006 *            http://www.netlib.org/lapack/explore-html/ 
00007 *
00008 *> \htmlonly
00009 *> Download DLA_SYRCOND + dependencies 
00010 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dla_syrcond.f"> 
00011 *> [TGZ]</a> 
00012 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dla_syrcond.f"> 
00013 *> [ZIP]</a> 
00014 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dla_syrcond.f"> 
00015 *> [TXT]</a>
00016 *> \endhtmlonly 
00017 *
00018 *  Definition:
00019 *  ===========
00020 *
00021 *       DOUBLE PRECISION FUNCTION DLA_SYRCOND( UPLO, N, A, LDA, AF, LDAF, 
00022 *                                              IPIV, CMODE, C, INFO, WORK,
00023 *                                              IWORK )
00024 * 
00025 *       .. Scalar Arguments ..
00026 *       CHARACTER          UPLO
00027 *       INTEGER            N, LDA, LDAF, INFO, CMODE
00028 *       ..
00029 *       .. Array Arguments
00030 *       INTEGER            IWORK( * ), IPIV( * )
00031 *       DOUBLE PRECISION   A( LDA, * ), AF( LDAF, * ), WORK( * ), C( * )
00032 *       ..
00033 *  
00034 *
00035 *> \par Purpose:
00036 *  =============
00037 *>
00038 *> \verbatim
00039 *>
00040 *>    DLA_SYRCOND estimates the Skeel condition number of  op(A) * op2(C)
00041 *>    where op2 is determined by CMODE as follows
00042 *>    CMODE =  1    op2(C) = C
00043 *>    CMODE =  0    op2(C) = I
00044 *>    CMODE = -1    op2(C) = inv(C)
00045 *>    The Skeel condition number cond(A) = norminf( |inv(A)||A| )
00046 *>    is computed by computing scaling factors R such that
00047 *>    diag(R)*A*op2(C) is row equilibrated and computing the standard
00048 *>    infinity-norm condition number.
00049 *> \endverbatim
00050 *
00051 *  Arguments:
00052 *  ==========
00053 *
00054 *> \param[in] UPLO
00055 *> \verbatim
00056 *>          UPLO is CHARACTER*1
00057 *>       = 'U':  Upper triangle of A is stored;
00058 *>       = 'L':  Lower triangle of A is stored.
00059 *> \endverbatim
00060 *>
00061 *> \param[in] N
00062 *> \verbatim
00063 *>          N is INTEGER
00064 *>     The number of linear equations, i.e., the order of the
00065 *>     matrix A.  N >= 0.
00066 *> \endverbatim
00067 *>
00068 *> \param[in] A
00069 *> \verbatim
00070 *>          A is DOUBLE PRECISION array, dimension (LDA,N)
00071 *>     On entry, the N-by-N matrix A.
00072 *> \endverbatim
00073 *>
00074 *> \param[in] LDA
00075 *> \verbatim
00076 *>          LDA is INTEGER
00077 *>     The leading dimension of the array A.  LDA >= max(1,N).
00078 *> \endverbatim
00079 *>
00080 *> \param[in] AF
00081 *> \verbatim
00082 *>          AF is DOUBLE PRECISION array, dimension (LDAF,N)
00083 *>     The block diagonal matrix D and the multipliers used to
00084 *>     obtain the factor U or L as computed by DSYTRF.
00085 *> \endverbatim
00086 *>
00087 *> \param[in] LDAF
00088 *> \verbatim
00089 *>          LDAF is INTEGER
00090 *>     The leading dimension of the array AF.  LDAF >= max(1,N).
00091 *> \endverbatim
00092 *>
00093 *> \param[in] IPIV
00094 *> \verbatim
00095 *>          IPIV is INTEGER array, dimension (N)
00096 *>     Details of the interchanges and the block structure of D
00097 *>     as determined by DSYTRF.
00098 *> \endverbatim
00099 *>
00100 *> \param[in] CMODE
00101 *> \verbatim
00102 *>          CMODE is INTEGER
00103 *>     Determines op2(C) in the formula op(A) * op2(C) as follows:
00104 *>     CMODE =  1    op2(C) = C
00105 *>     CMODE =  0    op2(C) = I
00106 *>     CMODE = -1    op2(C) = inv(C)
00107 *> \endverbatim
00108 *>
00109 *> \param[in] C
00110 *> \verbatim
00111 *>          C is DOUBLE PRECISION array, dimension (N)
00112 *>     The vector C in the formula op(A) * op2(C).
00113 *> \endverbatim
00114 *>
00115 *> \param[out] INFO
00116 *> \verbatim
00117 *>          INFO is INTEGER
00118 *>       = 0:  Successful exit.
00119 *>     i > 0:  The ith argument is invalid.
00120 *> \endverbatim
00121 *>
00122 *> \param[in] WORK
00123 *> \verbatim
00124 *>          WORK is DOUBLE PRECISION array, dimension (3*N).
00125 *>     Workspace.
00126 *> \endverbatim
00127 *>
00128 *> \param[in] IWORK
00129 *> \verbatim
00130 *>          IWORK is INTEGER array, dimension (N).
00131 *>     Workspace.
00132 *> \endverbatim
00133 *
00134 *  Authors:
00135 *  ========
00136 *
00137 *> \author Univ. of Tennessee 
00138 *> \author Univ. of California Berkeley 
00139 *> \author Univ. of Colorado Denver 
00140 *> \author NAG Ltd. 
00141 *
00142 *> \date November 2011
00143 *
00144 *> \ingroup doubleSYcomputational
00145 *
00146 *  =====================================================================
00147       DOUBLE PRECISION FUNCTION DLA_SYRCOND( UPLO, N, A, LDA, AF, LDAF, 
00148      $                                       IPIV, CMODE, C, INFO, WORK,
00149      $                                       IWORK )
00150 *
00151 *  -- LAPACK computational routine (version 3.4.0) --
00152 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00153 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00154 *     November 2011
00155 *
00156 *     .. Scalar Arguments ..
00157       CHARACTER          UPLO
00158       INTEGER            N, LDA, LDAF, INFO, CMODE
00159 *     ..
00160 *     .. Array Arguments
00161       INTEGER            IWORK( * ), IPIV( * )
00162       DOUBLE PRECISION   A( LDA, * ), AF( LDAF, * ), WORK( * ), C( * )
00163 *     ..
00164 *
00165 *  =====================================================================
00166 *
00167 *     .. Local Scalars ..
00168       CHARACTER          NORMIN
00169       INTEGER            KASE, I, J
00170       DOUBLE PRECISION   AINVNM, SMLNUM, TMP
00171       LOGICAL            UP
00172 *     ..
00173 *     .. Local Arrays ..
00174       INTEGER            ISAVE( 3 )
00175 *     ..
00176 *     .. External Functions ..
00177       LOGICAL            LSAME
00178       INTEGER            IDAMAX
00179       DOUBLE PRECISION   DLAMCH
00180       EXTERNAL           LSAME, IDAMAX, DLAMCH
00181 *     ..
00182 *     .. External Subroutines ..
00183       EXTERNAL           DLACN2, DLATRS, DRSCL, XERBLA, DSYTRS
00184 *     ..
00185 *     .. Intrinsic Functions ..
00186       INTRINSIC          ABS, MAX
00187 *     ..
00188 *     .. Executable Statements ..
00189 *
00190       DLA_SYRCOND = 0.0D+0
00191 *
00192       INFO = 0
00193       IF( N.LT.0 ) THEN
00194          INFO = -2
00195       END IF
00196       IF( INFO.NE.0 ) THEN
00197          CALL XERBLA( 'DLA_SYRCOND', -INFO )
00198          RETURN
00199       END IF
00200       IF( N.EQ.0 ) THEN
00201          DLA_SYRCOND = 1.0D+0
00202          RETURN
00203       END IF
00204       UP = .FALSE.
00205       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
00206 *
00207 *     Compute the equilibration matrix R such that
00208 *     inv(R)*A*C has unit 1-norm.
00209 *
00210       IF ( UP ) THEN
00211          DO I = 1, N
00212             TMP = 0.0D+0
00213             IF ( CMODE .EQ. 1 ) THEN
00214                DO J = 1, I
00215                   TMP = TMP + ABS( A( J, I ) * C( J ) )
00216                END DO
00217                DO J = I+1, N
00218                   TMP = TMP + ABS( A( I, J ) * C( J ) )
00219                END DO
00220             ELSE IF ( CMODE .EQ. 0 ) THEN
00221                DO J = 1, I
00222                   TMP = TMP + ABS( A( J, I ) )
00223                END DO
00224                DO J = I+1, N
00225                   TMP = TMP + ABS( A( I, J ) )
00226                END DO
00227             ELSE
00228                DO J = 1, I
00229                   TMP = TMP + ABS( A( J, I ) / C( J ) )
00230                END DO
00231                DO J = I+1, N
00232                   TMP = TMP + ABS( A( I, J ) / C( J ) )
00233                END DO
00234             END IF
00235             WORK( 2*N+I ) = TMP
00236          END DO
00237       ELSE
00238          DO I = 1, N
00239             TMP = 0.0D+0
00240             IF ( CMODE .EQ. 1 ) THEN
00241                DO J = 1, I
00242                   TMP = TMP + ABS( A( I, J ) * C( J ) )
00243                END DO
00244                DO J = I+1, N
00245                   TMP = TMP + ABS( A( J, I ) * C( J ) )
00246                END DO
00247             ELSE IF ( CMODE .EQ. 0 ) THEN
00248                DO J = 1, I
00249                   TMP = TMP + ABS( A( I, J ) )
00250                END DO
00251                DO J = I+1, N
00252                   TMP = TMP + ABS( A( J, I ) )
00253                END DO
00254             ELSE
00255                DO J = 1, I
00256                   TMP = TMP + ABS( A( I, J) / C( J ) )
00257                END DO
00258                DO J = I+1, N
00259                   TMP = TMP + ABS( A( J, I) / C( J ) )
00260                END DO
00261             END IF
00262             WORK( 2*N+I ) = TMP
00263          END DO
00264       ENDIF
00265 *
00266 *     Estimate the norm of inv(op(A)).
00267 *
00268       SMLNUM = DLAMCH( 'Safe minimum' )
00269       AINVNM = 0.0D+0
00270       NORMIN = 'N'
00271 
00272       KASE = 0
00273    10 CONTINUE
00274       CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
00275       IF( KASE.NE.0 ) THEN
00276          IF( KASE.EQ.2 ) THEN
00277 *
00278 *           Multiply by R.
00279 *
00280             DO I = 1, N
00281                WORK( I ) = WORK( I ) * WORK( 2*N+I )
00282             END DO
00283 
00284             IF ( UP ) THEN
00285                CALL DSYTRS( 'U', N, 1, AF, LDAF, IPIV, WORK, N, INFO )
00286             ELSE
00287                CALL DSYTRS( 'L', N, 1, AF, LDAF, IPIV, WORK, N, INFO )
00288             ENDIF
00289 *
00290 *           Multiply by inv(C).
00291 *
00292             IF ( CMODE .EQ. 1 ) THEN
00293                DO I = 1, N
00294                   WORK( I ) = WORK( I ) / C( I )
00295                END DO
00296             ELSE IF ( CMODE .EQ. -1 ) THEN
00297                DO I = 1, N
00298                   WORK( I ) = WORK( I ) * C( I )
00299                END DO
00300             END IF
00301          ELSE
00302 *
00303 *           Multiply by inv(C**T).
00304 *
00305             IF ( CMODE .EQ. 1 ) THEN
00306                DO I = 1, N
00307                   WORK( I ) = WORK( I ) / C( I )
00308                END DO
00309             ELSE IF ( CMODE .EQ. -1 ) THEN
00310                DO I = 1, N
00311                   WORK( I ) = WORK( I ) * C( I )
00312                END DO
00313             END IF
00314 
00315             IF ( UP ) THEN
00316                CALL DSYTRS( 'U', N, 1, AF, LDAF, IPIV, WORK, N, INFO )
00317             ELSE
00318                CALL DSYTRS( 'L', N, 1, AF, LDAF, IPIV, WORK, N, INFO )
00319             ENDIF
00320 *
00321 *           Multiply by R.
00322 *
00323             DO I = 1, N
00324                WORK( I ) = WORK( I ) * WORK( 2*N+I )
00325             END DO
00326          END IF
00327 *
00328          GO TO 10
00329       END IF
00330 *
00331 *     Compute the estimate of the reciprocal condition number.
00332 *
00333       IF( AINVNM .NE. 0.0D+0 )
00334      $   DLA_SYRCOND = ( 1.0D+0 / AINVNM )
00335 *
00336       RETURN
00337 *
00338       END