Go to the documentation of this file.
00001 *> \brief \b CUNMRQ
00002 *
00003 *  =========== DOCUMENTATION ===========
00004 *
00005 * Online html documentation available at 
00006 *            http://www.netlib.org/lapack/explore-html/ 
00007 *
00008 *> \htmlonly
00009 *> Download CUNMRQ + dependencies 
00010 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cunmrq.f"> 
00011 *> [TGZ]</a> 
00012 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cunmrq.f"> 
00013 *> [ZIP]</a> 
00014 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cunmrq.f"> 
00015 *> [TXT]</a>
00016 *> \endhtmlonly 
00017 *
00018 *  Definition:
00019 *  ===========
00020 *
00021 *       SUBROUTINE CUNMRQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
00022 *                          WORK, LWORK, INFO )
00023 * 
00024 *       .. Scalar Arguments ..
00025 *       CHARACTER          SIDE, TRANS
00026 *       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
00027 *       ..
00028 *       .. Array Arguments ..
00029 *       COMPLEX            A( LDA, * ), C( LDC, * ), TAU( * ),
00030 *      $                   WORK( * )
00031 *       ..
00032 *  
00033 *
00034 *> \par Purpose:
00035 *  =============
00036 *>
00037 *> \verbatim
00038 *>
00039 *> CUNMRQ overwrites the general complex M-by-N matrix C with
00040 *>
00041 *>                 SIDE = 'L'     SIDE = 'R'
00042 *> TRANS = 'N':      Q * C          C * Q
00043 *> TRANS = 'C':      Q**H * C       C * Q**H
00044 *>
00045 *> where Q is a complex unitary matrix defined as the product of k
00046 *> elementary reflectors
00047 *>
00048 *>       Q = H(1)**H H(2)**H . . . H(k)**H
00049 *>
00050 *> as returned by CGERQF. Q is of order M if SIDE = 'L' and of order N
00051 *> if SIDE = 'R'.
00052 *> \endverbatim
00053 *
00054 *  Arguments:
00055 *  ==========
00056 *
00057 *> \param[in] SIDE
00058 *> \verbatim
00059 *>          SIDE is CHARACTER*1
00060 *>          = 'L': apply Q or Q**H from the Left;
00061 *>          = 'R': apply Q or Q**H from the Right.
00062 *> \endverbatim
00063 *>
00064 *> \param[in] TRANS
00065 *> \verbatim
00066 *>          TRANS is CHARACTER*1
00067 *>          = 'N':  No transpose, apply Q;
00068 *>          = 'C':  Transpose, apply Q**H.
00069 *> \endverbatim
00070 *>
00071 *> \param[in] M
00072 *> \verbatim
00073 *>          M is INTEGER
00074 *>          The number of rows of the matrix C. M >= 0.
00075 *> \endverbatim
00076 *>
00077 *> \param[in] N
00078 *> \verbatim
00079 *>          N is INTEGER
00080 *>          The number of columns of the matrix C. N >= 0.
00081 *> \endverbatim
00082 *>
00083 *> \param[in] K
00084 *> \verbatim
00085 *>          K is INTEGER
00086 *>          The number of elementary reflectors whose product defines
00087 *>          the matrix Q.
00088 *>          If SIDE = 'L', M >= K >= 0;
00089 *>          if SIDE = 'R', N >= K >= 0.
00090 *> \endverbatim
00091 *>
00092 *> \param[in] A
00093 *> \verbatim
00094 *>          A is COMPLEX array, dimension
00095 *>                               (LDA,M) if SIDE = 'L',
00096 *>                               (LDA,N) if SIDE = 'R'
00097 *>          The i-th row must contain the vector which defines the
00098 *>          elementary reflector H(i), for i = 1,2,...,k, as returned by
00099 *>          CGERQF in the last k rows of its array argument A.
00100 *>          A is modified by the routine but restored on exit.
00101 *> \endverbatim
00102 *>
00103 *> \param[in] LDA
00104 *> \verbatim
00105 *>          LDA is INTEGER
00106 *>          The leading dimension of the array A. LDA >= max(1,K).
00107 *> \endverbatim
00108 *>
00109 *> \param[in] TAU
00110 *> \verbatim
00111 *>          TAU is COMPLEX array, dimension (K)
00112 *>          TAU(i) must contain the scalar factor of the elementary
00113 *>          reflector H(i), as returned by CGERQF.
00114 *> \endverbatim
00115 *>
00116 *> \param[in,out] C
00117 *> \verbatim
00118 *>          C is COMPLEX array, dimension (LDC,N)
00119 *>          On entry, the M-by-N matrix C.
00120 *>          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
00121 *> \endverbatim
00122 *>
00123 *> \param[in] LDC
00124 *> \verbatim
00125 *>          LDC is INTEGER
00126 *>          The leading dimension of the array C. LDC >= max(1,M).
00127 *> \endverbatim
00128 *>
00129 *> \param[out] WORK
00130 *> \verbatim
00131 *>          WORK is COMPLEX array, dimension (MAX(1,LWORK))
00132 *>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
00133 *> \endverbatim
00134 *>
00135 *> \param[in] LWORK
00136 *> \verbatim
00137 *>          LWORK is INTEGER
00138 *>          The dimension of the array WORK.
00139 *>          If SIDE = 'L', LWORK >= max(1,N);
00140 *>          if SIDE = 'R', LWORK >= max(1,M).
00141 *>          For optimum performance LWORK >= N*NB if SIDE = 'L', and
00142 *>          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
00143 *>          blocksize.
00144 *>
00145 *>          If LWORK = -1, then a workspace query is assumed; the routine
00146 *>          only calculates the optimal size of the WORK array, returns
00147 *>          this value as the first entry of the WORK array, and no error
00148 *>          message related to LWORK is issued by XERBLA.
00149 *> \endverbatim
00150 *>
00151 *> \param[out] INFO
00152 *> \verbatim
00153 *>          INFO is INTEGER
00154 *>          = 0:  successful exit
00155 *>          < 0:  if INFO = -i, the i-th argument had an illegal value
00156 *> \endverbatim
00157 *
00158 *  Authors:
00159 *  ========
00160 *
00161 *> \author Univ. of Tennessee 
00162 *> \author Univ. of California Berkeley 
00163 *> \author Univ. of Colorado Denver 
00164 *> \author NAG Ltd. 
00165 *
00166 *> \date November 2011
00167 *
00168 *> \ingroup complexOTHERcomputational
00169 *
00170 *  =====================================================================
00171       SUBROUTINE CUNMRQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
00172      $                   WORK, LWORK, INFO )
00173 *
00174 *  -- LAPACK computational routine (version 3.4.0) --
00175 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00176 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00177 *     November 2011
00178 *
00179 *     .. Scalar Arguments ..
00180       CHARACTER          SIDE, TRANS
00181       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
00182 *     ..
00183 *     .. Array Arguments ..
00184       COMPLEX            A( LDA, * ), C( LDC, * ), TAU( * ),
00185      $                   WORK( * )
00186 *     ..
00187 *
00188 *  =====================================================================
00189 *
00190 *     .. Parameters ..
00191       INTEGER            NBMAX, LDT
00192       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
00193 *     ..
00194 *     .. Local Scalars ..
00195       LOGICAL            LEFT, LQUERY, NOTRAN
00196       CHARACTER          TRANST
00197       INTEGER            I, I1, I2, I3, IB, IINFO, IWS, LDWORK, LWKOPT,
00198      $                   MI, NB, NBMIN, NI, NQ, NW
00199 *     ..
00200 *     .. Local Arrays ..
00201       COMPLEX            T( LDT, NBMAX )
00202 *     ..
00203 *     .. External Functions ..
00204       LOGICAL            LSAME
00205       INTEGER            ILAENV
00206       EXTERNAL           LSAME, ILAENV
00207 *     ..
00208 *     .. External Subroutines ..
00209       EXTERNAL           CLARFB, CLARFT, CUNMR2, XERBLA
00210 *     ..
00211 *     .. Intrinsic Functions ..
00212       INTRINSIC          MAX, MIN
00213 *     ..
00214 *     .. Executable Statements ..
00215 *
00216 *     Test the input arguments
00217 *
00218       INFO = 0
00219       LEFT = LSAME( SIDE, 'L' )
00220       NOTRAN = LSAME( TRANS, 'N' )
00221       LQUERY = ( LWORK.EQ.-1 )
00222 *
00223 *     NQ is the order of Q and NW is the minimum dimension of WORK
00224 *
00225       IF( LEFT ) THEN
00226          NQ = M
00227          NW = MAX( 1, N )
00228       ELSE
00229          NQ = N
00230          NW = MAX( 1, M )
00231       END IF
00232       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
00233          INFO = -1
00234       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
00235          INFO = -2
00236       ELSE IF( M.LT.0 ) THEN
00237          INFO = -3
00238       ELSE IF( N.LT.0 ) THEN
00239          INFO = -4
00240       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
00241          INFO = -5
00242       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
00243          INFO = -7
00244       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
00245          INFO = -10
00246       END IF
00247 *
00248       IF( INFO.EQ.0 ) THEN
00249          IF( M.EQ.0 .OR. N.EQ.0 ) THEN
00250             LWKOPT = 1
00251          ELSE
00252 *
00253 *           Determine the block size.  NB may be at most NBMAX, where
00254 *           NBMAX is used to define the local array T.
00255 *
00256             NB = MIN( NBMAX, ILAENV( 1, 'CUNMRQ', SIDE // TRANS, M, N,
00257      $                               K, -1 ) )
00258             LWKOPT = NW*NB
00259          END IF
00260          WORK( 1 ) = LWKOPT
00261 *
00262          IF( LWORK.LT.NW .AND. .NOT.LQUERY ) THEN
00263             INFO = -12
00264          END IF
00265       END IF
00266 *
00267       IF( INFO.NE.0 ) THEN
00268          CALL XERBLA( 'CUNMRQ', -INFO )
00269          RETURN
00270       ELSE IF( LQUERY ) THEN
00271          RETURN
00272       END IF
00273 *
00274 *     Quick return if possible
00275 *
00276       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
00277          RETURN
00278       END IF
00279 *
00280       NBMIN = 2
00281       LDWORK = NW
00282       IF( NB.GT.1 .AND. NB.LT.K ) THEN
00283          IWS = NW*NB
00284          IF( LWORK.LT.IWS ) THEN
00285             NB = LWORK / LDWORK
00286             NBMIN = MAX( 2, ILAENV( 2, 'CUNMRQ', SIDE // TRANS, M, N, K,
00287      $              -1 ) )
00288          END IF
00289       ELSE
00290          IWS = NW
00291       END IF
00292 *
00293       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
00294 *
00295 *        Use unblocked code
00296 *
00297          CALL CUNMR2( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
00298      $                IINFO )
00299       ELSE
00300 *
00301 *        Use blocked code
00302 *
00303          IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
00304      $       ( .NOT.LEFT .AND. NOTRAN ) ) THEN
00305             I1 = 1
00306             I2 = K
00307             I3 = NB
00308          ELSE
00309             I1 = ( ( K-1 ) / NB )*NB + 1
00310             I2 = 1
00311             I3 = -NB
00312          END IF
00313 *
00314          IF( LEFT ) THEN
00315             NI = N
00316          ELSE
00317             MI = M
00318          END IF
00319 *
00320          IF( NOTRAN ) THEN
00321             TRANST = 'C'
00322          ELSE
00323             TRANST = 'N'
00324          END IF
00325 *
00326          DO 10 I = I1, I2, I3
00327             IB = MIN( NB, K-I+1 )
00328 *
00329 *           Form the triangular factor of the block reflector
00330 *           H = H(i+ib-1) . . . H(i+1) H(i)
00331 *
00332             CALL CLARFT( 'Backward', 'Rowwise', NQ-K+I+IB-1, IB,
00333      $                   A( I, 1 ), LDA, TAU( I ), T, LDT )
00334             IF( LEFT ) THEN
00335 *
00336 *              H or H**H is applied to C(1:m-k+i+ib-1,1:n)
00337 *
00338                MI = M - K + I + IB - 1
00339             ELSE
00340 *
00341 *              H or H**H is applied to C(1:m,1:n-k+i+ib-1)
00342 *
00343                NI = N - K + I + IB - 1
00344             END IF
00345 *
00346 *           Apply H or H**H
00347 *
00348             CALL CLARFB( SIDE, TRANST, 'Backward', 'Rowwise', MI, NI,
00349      $                   IB, A( I, 1 ), LDA, T, LDT, C, LDC, WORK,
00350      $                   LDWORK )
00351    10    CONTINUE
00352       END IF
00353       WORK( 1 ) = LWKOPT
00354       RETURN
00355 *
00356 *     End of CUNMRQ
00357 *
00358       END