Go to the documentation of this file.
00001 *> \brief \b ZLA_HERCOND_X
00002 *
00003 *  =========== DOCUMENTATION ===========
00004 *
00005 * Online html documentation available at 
00006 *            http://www.netlib.org/lapack/explore-html/ 
00007 *
00008 *> \htmlonly
00009 *> Download ZLA_HERCOND_X + dependencies 
00010 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zla_hercond_x.f"> 
00011 *> [TGZ]</a> 
00012 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zla_hercond_x.f"> 
00013 *> [ZIP]</a> 
00014 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zla_hercond_x.f"> 
00015 *> [TXT]</a>
00016 *> \endhtmlonly 
00017 *
00018 *  Definition:
00019 *  ===========
00020 *
00021 *       DOUBLE PRECISION FUNCTION ZLA_HERCOND_X( UPLO, N, A, LDA, AF,
00022 *                                                LDAF, IPIV, X, INFO,
00023 *                                                WORK, RWORK )
00024 * 
00025 *       .. Scalar Arguments ..
00026 *       CHARACTER          UPLO
00027 *       INTEGER            N, LDA, LDAF, INFO
00028 *       ..
00029 *       .. Array Arguments ..
00030 *       INTEGER            IPIV( * )
00031 *       COMPLEX*16         A( LDA, * ), AF( LDAF, * ), WORK( * ), X( * )
00032 *       DOUBLE PRECISION   RWORK( * )
00033 *       ..
00034 *  
00035 *
00036 *> \par Purpose:
00037 *  =============
00038 *>
00039 *> \verbatim
00040 *>
00041 *>    ZLA_HERCOND_X computes the infinity norm condition number of
00042 *>    op(A) * diag(X) where X is a COMPLEX*16 vector.
00043 *> \endverbatim
00044 *
00045 *  Arguments:
00046 *  ==========
00047 *
00048 *> \param[in] UPLO
00049 *> \verbatim
00050 *>          UPLO is CHARACTER*1
00051 *>       = 'U':  Upper triangle of A is stored;
00052 *>       = 'L':  Lower triangle of A is stored.
00053 *> \endverbatim
00054 *>
00055 *> \param[in] N
00056 *> \verbatim
00057 *>          N is INTEGER
00058 *>     The number of linear equations, i.e., the order of the
00059 *>     matrix A.  N >= 0.
00060 *> \endverbatim
00061 *>
00062 *> \param[in] A
00063 *> \verbatim
00064 *>          A is COMPLEX*16 array, dimension (LDA,N)
00065 *>     On entry, the N-by-N matrix A.
00066 *> \endverbatim
00067 *>
00068 *> \param[in] LDA
00069 *> \verbatim
00070 *>          LDA is INTEGER
00071 *>     The leading dimension of the array A.  LDA >= max(1,N).
00072 *> \endverbatim
00073 *>
00074 *> \param[in] AF
00075 *> \verbatim
00076 *>          AF is COMPLEX*16 array, dimension (LDAF,N)
00077 *>     The block diagonal matrix D and the multipliers used to
00078 *>     obtain the factor U or L as computed by ZHETRF.
00079 *> \endverbatim
00080 *>
00081 *> \param[in] LDAF
00082 *> \verbatim
00083 *>          LDAF is INTEGER
00084 *>     The leading dimension of the array AF.  LDAF >= max(1,N).
00085 *> \endverbatim
00086 *>
00087 *> \param[in] IPIV
00088 *> \verbatim
00089 *>          IPIV is INTEGER array, dimension (N)
00090 *>     Details of the interchanges and the block structure of D
00091 *>     as determined by CHETRF.
00092 *> \endverbatim
00093 *>
00094 *> \param[in] X
00095 *> \verbatim
00096 *>          X is COMPLEX*16 array, dimension (N)
00097 *>     The vector X in the formula op(A) * diag(X).
00098 *> \endverbatim
00099 *>
00100 *> \param[out] INFO
00101 *> \verbatim
00102 *>          INFO is INTEGER
00103 *>       = 0:  Successful exit.
00104 *>     i > 0:  The ith argument is invalid.
00105 *> \endverbatim
00106 *>
00107 *> \param[in] WORK
00108 *> \verbatim
00109 *>          WORK is COMPLEX*16 array, dimension (2*N).
00110 *>     Workspace.
00111 *> \endverbatim
00112 *>
00113 *> \param[in] RWORK
00114 *> \verbatim
00115 *>          RWORK is DOUBLE PRECISION array, dimension (N).
00116 *>     Workspace.
00117 *> \endverbatim
00118 *
00119 *  Authors:
00120 *  ========
00121 *
00122 *> \author Univ. of Tennessee 
00123 *> \author Univ. of California Berkeley 
00124 *> \author Univ. of Colorado Denver 
00125 *> \author NAG Ltd. 
00126 *
00127 *> \date November 2011
00128 *
00129 *> \ingroup complex16HEcomputational
00130 *
00131 *  =====================================================================
00132       DOUBLE PRECISION FUNCTION ZLA_HERCOND_X( UPLO, N, A, LDA, AF,
00133      $                                         LDAF, IPIV, X, INFO,
00134      $                                         WORK, RWORK )
00135 *
00136 *  -- LAPACK computational routine (version 3.4.0) --
00137 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00138 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00139 *     November 2011
00140 *
00141 *     .. Scalar Arguments ..
00142       CHARACTER          UPLO
00143       INTEGER            N, LDA, LDAF, INFO
00144 *     ..
00145 *     .. Array Arguments ..
00146       INTEGER            IPIV( * )
00147       COMPLEX*16         A( LDA, * ), AF( LDAF, * ), WORK( * ), X( * )
00148       DOUBLE PRECISION   RWORK( * )
00149 *     ..
00150 *
00151 *  =====================================================================
00152 *
00153 *     .. Local Scalars ..
00154       INTEGER            KASE, I, J
00155       DOUBLE PRECISION   AINVNM, ANORM, TMP
00156       LOGICAL            UP
00157       COMPLEX*16         ZDUM
00158 *     ..
00159 *     .. Local Arrays ..
00160       INTEGER            ISAVE( 3 )
00161 *     ..
00162 *     .. External Functions ..
00163       LOGICAL            LSAME
00164       EXTERNAL           LSAME
00165 *     ..
00166 *     .. External Subroutines ..
00167       EXTERNAL           ZLACN2, ZHETRS, XERBLA
00168 *     ..
00169 *     .. Intrinsic Functions ..
00170       INTRINSIC          ABS, MAX
00171 *     ..
00172 *     .. Statement Functions ..
00173       DOUBLE PRECISION CABS1
00174 *     ..
00175 *     .. Statement Function Definitions ..
00176       CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
00177 *     ..
00178 *     .. Executable Statements ..
00179 *
00180       ZLA_HERCOND_X = 0.0D+0
00181 *
00182       INFO = 0
00183       IF( N.LT.0 ) THEN
00184          INFO = -2
00185       END IF
00186       IF( INFO.NE.0 ) THEN
00187          CALL XERBLA( 'ZLA_HERCOND_X', -INFO )
00188          RETURN
00189       END IF
00190       UP = .FALSE.
00191       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
00192 *
00193 *     Compute norm of op(A)*op2(C).
00194 *
00195       ANORM = 0.0D+0
00196       IF ( UP ) THEN
00197          DO I = 1, N
00198             TMP = 0.0D+0
00199             DO J = 1, I
00200                TMP = TMP + CABS1( A( J, I ) * X( J ) )
00201             END DO
00202             DO J = I+1, N
00203                TMP = TMP + CABS1( A( I, J ) * X( J ) )
00204             END DO
00205             RWORK( I ) = TMP
00206             ANORM = MAX( ANORM, TMP )
00207          END DO
00208       ELSE
00209          DO I = 1, N
00210             TMP = 0.0D+0
00211             DO J = 1, I
00212                TMP = TMP + CABS1( A( I, J ) * X( J ) )
00213             END DO
00214             DO J = I+1, N
00215                TMP = TMP + CABS1( A( J, I ) * X( J ) )
00216             END DO
00217             RWORK( I ) = TMP
00218             ANORM = MAX( ANORM, TMP )
00219          END DO
00220       END IF
00221 *
00222 *     Quick return if possible.
00223 *
00224       IF( N.EQ.0 ) THEN
00225          ZLA_HERCOND_X = 1.0D+0
00226          RETURN
00227       ELSE IF( ANORM .EQ. 0.0D+0 ) THEN
00228          RETURN
00229       END IF
00230 *
00231 *     Estimate the norm of inv(op(A)).
00232 *
00233       AINVNM = 0.0D+0
00234 *
00235       KASE = 0
00236    10 CONTINUE
00237       CALL ZLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
00238       IF( KASE.NE.0 ) THEN
00239          IF( KASE.EQ.2 ) THEN
00240 *
00241 *           Multiply by R.
00242 *
00243             DO I = 1, N
00244                WORK( I ) = WORK( I ) * RWORK( I )
00245             END DO
00246 *
00247             IF ( UP ) THEN
00248                CALL ZHETRS( 'U', N, 1, AF, LDAF, IPIV,
00249      $            WORK, N, INFO )
00250             ELSE
00251                CALL ZHETRS( 'L', N, 1, AF, LDAF, IPIV,
00252      $            WORK, N, INFO )
00253             ENDIF
00254 *
00255 *           Multiply by inv(X).
00256 *
00257             DO I = 1, N
00258                WORK( I ) = WORK( I ) / X( I )
00259             END DO
00260          ELSE
00261 *
00262 *           Multiply by inv(X**H).
00263 *
00264             DO I = 1, N
00265                WORK( I ) = WORK( I ) / X( I )
00266             END DO
00267 *
00268             IF ( UP ) THEN
00269                CALL ZHETRS( 'U', N, 1, AF, LDAF, IPIV,
00270      $            WORK, N, INFO )
00271             ELSE
00272                CALL ZHETRS( 'L', N, 1, AF, LDAF, IPIV,
00273      $            WORK, N, INFO )
00274             END IF
00275 *
00276 *           Multiply by R.
00277 *
00278             DO I = 1, N
00279                WORK( I ) = WORK( I ) * RWORK( I )
00280             END DO
00281          END IF
00282          GO TO 10
00283       END IF
00284 *
00285 *     Compute the estimate of the reciprocal condition number.
00286 *
00287       IF( AINVNM .NE. 0.0D+0 )
00288      $   ZLA_HERCOND_X = 1.0D+0 / AINVNM
00289 *
00290       RETURN
00291 *
00292       END