/*
 *  Licensed to the Apache Software Foundation (ASF) under one
 *  or more contributor license agreements.  See the NOTICE file
 *  distributed with this work for additional information
 *  regarding copyright ownership.  The ASF licenses this file
 *  to you under the Apache License, Version 2.0 (the
 *  "License"); you may not use this file except in compliance
 *  with the License.  You may obtain a copy of the License at
 *
 *    https://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing,
 *  software distributed under the License is distributed on an
 *  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 *  KIND, either express or implied.  See the License for the
 *  specific language governing permissions and limitations
 *  under the License.
 */
package grails.plugin.springsecurity.web

import groovy.transform.CompileStatic
import groovy.util.logging.Slf4j

import jakarta.servlet.Filter
import jakarta.servlet.http.HttpServletRequest

import org.springframework.security.web.SecurityFilterChain
import org.springframework.security.web.util.matcher.AntPathRequestMatcher
import org.springframework.security.web.util.matcher.RequestMatcher

/**
 * Based on org.springframework.security.web.DefaultSecurityFilterChain which is final.
 *
 * @author Burt Beckwith
 */
@CompileStatic
@Slf4j
class GrailsSecurityFilterChain implements SecurityFilterChain {

    final RequestMatcher requestMatcher
    final List<Filter> filters
    final String matcherPattern

    GrailsSecurityFilterChain(String matcherPattern, List<Filter> filters) {
        this.filters = filters.collect() // copy
        this.matcherPattern = matcherPattern
        requestMatcher = new AntPathRequestMatcher(matcherPattern, null, false)
        log.info 'Creating filter chain: {}, {}', requestMatcher, filters
    }

    boolean matches(HttpServletRequest request) {
        requestMatcher.matches request
    }

    String toString() {
        "[$requestMatcher, $filters]"
    }
}
